Exercise 23: Control
Much of the material in this exercise is taken from The SumoBot Manual .  While you are not required to read this material, it is recommended.

1.  The code below is a modification of the basic sumobot competition program provided by Parallax.  Study the code and try to understand how it works.  Install the photoresistors, IR detectors, and IR emitters (also install the speaker and LED if desired) on your boe-bot per the Boe-Bot component sheets.  Load the program below into the Basic Stamp Editor and modify it to match your component installations.  Test the functionality of your sumobot.  Use white paper on the black table top to simulate the boundary of the competition ring shown below.

Describe the modifications that you made to the program below.

	' {$STAMP BS2}

' {$PBASIC 2.5}

' -----[ I/O Definitions ]------------------------------------------------------

LMotor          CON     14                      ' left servo motor

RMotor          CON     15                      ' right servo motor

LLineSnsIn      CON      5                      ' CHANGE THIS NUMBER---left line sensor input

RLineSnsIn      CON      9                      ' CHANGE THIS NUMBER---right line sensor input

LfIrOut         CON      12                     ' CHANGE THIS NUMBER---left IR LED output

LfIrIn          VAR     IN13                    ' CHANGE THIS NUMBER---left IR sensor input

RtIrOut         CON      1                      ' CHANGE THIS NUMBER---right IR LED output

RtIrIn          VAR     IN0                     ' CHANGE THIS NUMBER---right IR sensor input

Speaker         CON      1                      ' piezo speaker

StartLED        CON      0                      ' display start delay

' -----[ Constants ]------------------------------------------------------------

LFwdFast        CON     1000                    ' left motor forward; fast

LFwdSlow        CON      800                    ' left motor forward; slow

LStop           CON      750                    ' left motor stop

LRevSlow        CON      700                    ' left motor reverse; slow

LRevFast        CON      500                    ' left motor reverse; fast

RFwdFast        CON      500                    ' right motor forward; fast

RFwdSlow        CON      700                    ' right motor forward; slow

RStop           CON      750                    ' right motor stop

RRevSlow        CON      800                    ' right motor reverse; slow

RRevFast        CON     1000                    ' right motor reverse; fast

' -----[ Variables ]------------------------------------------------------------

oldLeft         VAR     Word

oldRight        VAR     Word

leftSense       VAR     Word                    ' left sensor raw reading

rightSense      VAR     Word                    ' right sensor raw reading

rightThresh     VAR     Word                    ' right black threshold setting

leftThresh      VAR     Word                    ' left black threshold setting

lineBits        VAR     Nib                     ' decoded sensors value

lineLeft        VAR     lineBits.BIT1

lineRight       VAR     lineBits.BIT0

irBits          VAR     Nib                     ' storage for IR target data

irLeft          VAR     irBits.BIT1

irRight         VAR     irBits.BIT0

lastIr          VAR     Nib                     ' info from last reading

pulses          VAR     Byte                    ' counter for motor control

temp            VAR     Byte

' -----[ Initialization ]-------------------------------------------------------

' Sets black threshold to 1/4 the average of the two sensor readings.

' SumoBot must be placed over black playing surface before this code runs.

Set_Threshold:                                  ' set photoresistor black threshold

  GOSUB Read_Line_Sensors

  oldRight = rightSense

  oldLeft = leftSense

  GOSUB Read_Line_Sensors

  leftThresh = (leftSense / 4) + (oldLeft / 4)

  rightThresh = (rightSense / 4) + (oldRight / 4)

  'DEBUG CR, "rightthresh "

  'DEBUG DEC rightThresh, CR

  'DEBUG CR, "leftthresh "

  'DEBUG DEC leftThresh, CR

Start_Delay:                                    ' mandatory five second delay

  FOR temp = 1 TO 5

    HIGH StartLED                               ' show active

    PAUSE 900

    INPUT StartLED                              ' blink each second

    FREQOUT Speaker, 100, 2500, 3000            ' beep each second

  NEXT

  GOTO Lunge                                    ' start aggressive!

' -----[ Main Code ]------------------------------------------------------------

Main:

  GOSUB Read_Line_Sensors

  ' If not on the Shikiri line (border), continue to look for opponent,

  ' otherwise, spin back toward center and resume search

  'DEBUG "linebits = ", DEC lineBits, CR

  ON lineBits GOTO Search_For_Opponent, Spin_Left, Spin_Right, About_Face

' --[ Border Avoidance ]--

Spin_Left:                                      ' right sensor was active

  FOR pulses = 1 TO 20

    PULSOUT LMotor, LRevFast

    PULSOUT RMotor, RFwdFast

    PAUSE 20

  NEXT

  lastIr = %00               ' clear scan direction

  GOTO Lunge

Spin_Right:                                     ' left sensor was active

  FOR pulses = 1 TO 20

    PULSOUT LMotor, LFwdFast

    PULSOUT RMotor, RRevFast

    PAUSE 20

  NEXT

  lastIr = %00

  GOTO Lunge

About_Face:                                     ' both sensors on Shikiri line

  FOR pulses = 1 TO 10                          ' back up from edge

    PULSOUT LMotor, LRevFast

    PULSOUT RMotor, RRevFast

    PAUSE 20

  NEXT

  FOR pulses = 1 TO 30                          ' turn around

    PULSOUT LMotor, LFwdFast

    PULSOUT RMotor, RRevFast

    PAUSE 20

  NEXT

  lastIr = %00

  GOTO Lunge

' --[ IR Processing ]--

Search_For_Opponent:

  GOSUB Read_IR_Sensors

  ' If opponent is not in view, scan last known direction.  Turn toward

  ' opponent if seen by one "eye" -- if both, lunge forward

  ON irBits GOTO Scan, Follow_Right, Follow_Left, Lunge

Scan:

  DEBUG "in scan", CR

  ON lastIR GOTO Move_Fwd, Scan_Right, Scan_Left

Move_Fwd:

  GOSUB Creep_Forward

  GOTO Main

Scan_Right:                                     ' spin right, slow

  FOR pulses = 1 TO 5

    PULSOUT LMotor, LFwdSlow

    PULSOUT RMotor, RRevSlow

    PAUSE 20

  NEXT

  GOSUB Creep_Forward                           ' keep moving

  GOTO Main

Scan_Left:                                      ' spin left, slow

  FOR pulses = 1 TO 5

    PULSOUT LMotor, LRevSlow

    PULSOUT RMotor, RFwdSlow

    PAUSE 20

  NEXT

  GOSUB Creep_Forward

  GOTO Main

Follow_Right:                                   ' spin right, fast

  PULSOUT LMotor, LFwdFast

  PULSOUT RMotor, RRevSlow

  lastIR = irBits                               ' save last direction found

  GOTO Main

Follow_Left:                                    ' spin left, fast

  PULSOUT LMotor, LRevSlow

  PULSOUT RMotor, RFwdFast

  lastIR = irBits

  GOTO Main

Lunge:                                          ' locked on -- go get him!

  FOR pulses = 1 TO 15

    PULSOUT LMotor, LFwdFast

    PULSOUT RMotor, RFwdFast

    PAUSE 20

  NEXT

  PULSOUT LMotor, LFwdFast

  PULSOUT RMotor, RFwdFast

  GOTO Main

' -----[ Subroutines ]----------------------------------------------------------

Read_Line_Sensors:

  HIGH LLineSnsIn                               ' discharge QTI caps

  HIGH RLineSnsIn

  PAUSE 10

  RCTIME LLineSnsIn, 1, leftSense               ' read left sensor

  RCTIME RLineSnsIn, 1, rightSense              ' read right sensor

  'DEBUG "right = ", DEC rightsense, CR

  'DEBUG "left = ", DEC leftsense, CR

  'PAUSE 500

  ' convert readings to bits

  lineBits = %00

  LOOKDOWN leftSense, >=[leftThresh, 0], lineLeft

  LOOKDOWN rightSense, >=[rightThresh, 0], lineRight

  RETURN

Read_IR_Sensors:

  FREQOUT LfIrOut, 1, 38500                     ' modulate left IR LED

  irLeft = ~LfIrIn                              ' read input (1 = target)

  FREQOUT RtIrOut, 1, 38500                     ' modulate right IR LED

  irRight = ~RtIrIn

  'DEBUG CLS

  'DEBUG "left IR = ", BIN irleft, CR

  'DEBUG "right IR = ", BIN irright, CR

  'PAUSE 500

  RETURN

Creep_Forward:

  FOR pulses = 1 TO 10

    PULSOUT LMotor, LFwdSlow

    PULSOUT RMotor, RFwdSlow

    PAUSE 20

  NEXT

  PULSOUT LMotor, LFwdSlow

  PULSOUT RMotor, RFwdSlow

  RETURN




2.  One of the difficulties that you will encounter if you use the servos motors to drive the sumobot (NOTE: You can also choose to use the Lego motors to drive the sumobot.) is maintaining the 20ms intervals on the control pulses.  If you shorten that interval (say send a signal every 7ms), the boe-bot will jitter.  If you send the signal too rarely (say every 50ms) then the boe-bot will stop.  Of course, you can pause for 20ms between each servo command but that takes alot of processor time which limits the other activities your boe-bot can perform.
The code on the left below defines a subroutine that can be used to address this problem.  A pulse command is sent to the servos only every fifth time the act subroutine is called.  Right now this code should give roughly the same performance as the program on the right below.  If the main loop contained calls to other subroutines (besides act) the value of aDur could be reduced to maintain a 20ms pulse interval and still allow for other processing steps.
Run the code on the left and observe the effect of varying the value of aDur on servo performance.

	main:

  GOSUB act
  GOTO main
act:

   if aDur > 0 then aDec

   aDur = 5

   pulsout LEFT,750

   pulsout RIGHT,750

   goto aDone

aDec:

   aDur = aDur - 1

aDone:

   return


	main:

  GOSUB act
  GOTO main
act:

   for I = 1 to 10

      pulsout LEFT,750

      pulsout RIGHT,750

      pause 20

   next

   return




	Value of aDur
	Servo performance

	aDur=1
	

	aDur=3
	

	aDur=5
	

	aDur =7
	

	aDur=9
	

	aDur=11
	











